FIGLet web interface [was: Kanie]

In article <39D...@gtcom.net>, Krogg wrote:
>Veronica Karlsson wrote:
>> 
>> And *what* am I supposed to do with *that* garbage? I meant like this:
>> 
>> http://www.surfplaza.com/figlet/
>> 
>> I always use Figlet on the web! I don't have the quota to keep software
>> on my account. Either it's "on the system", on the web or I live without
>> it.
>> 
>Well,there aint much i can do about that........HOW many fonts
>are avalible on the typical figlet web-interface.

Mine has 17, but of course that's only a test setup.  The code, which
I wrote to show that accepting arbitrary strings to figletize can be
done safely, is in public domain if anyone wants to use it to set up a
proper figlet server:

#!/usr/bin/perl -w
use strict;
use CGI::Carp qw/fatalsToBrowser/;
use CGI qw/:all escapeHTML/;

my $figlet = '/home/i/l/iltzu/figlet22/figlet';
my $fonts = '/home/i/l/iltzu/figlet22/fonts';

#
# Read list of available fonts
#
opendir FONTS, $fonts
    or die "Can't open font directory: $!\n";

my %fonts;
@fonts{grep s/\.flf$// => readdir FONTS} = ();

closedir FONTS
    or die "Error closing font directory: $!\n";

#
# Check parameters
#
param(font => 'standard')
    unless exists $fonts{param('font') || ''};
param(width => 80)
    unless (param('width') || 0) > 0;

#
# Generate form
#
print(header(),
      start_html('FIGLet WWW Interface'),
      startform(),
      table(Tr(td('Text:'),
	       td({-colspan => 4},
		  textfield(-name => 'text',
			    -size => 60))),
	    Tr(td('Font:'),
	       td(popup_menu(-name => 'font',
			     -values => [sort keys %fonts])),
	       td('Screen width:'),
	       td(textfield(-name => 'width',
			    -size => 5)),
	       td({-align => 'right'},
		  submit(-value => 'FIGLetize!')))),
      endform());

#
# FIGLetize input
#
if (length (param('text') || '')) {
    my $pid = open FIGLET, "-|";
    die "Can't fork" unless defined $pid;
    exec($figlet,
	 -d => $fonts,
	 -f => scalar param('font'),
	 -w => scalar param('width'),
	 param('text')) unless $pid;
    
    print "<HR>\n<PRE>\n";
    while (<FIGLET>) {
	print escapeHTML($_);
    }
    print "</PRE>\n";
    close FIGLET
	or die "Error running FIGLet: $!\n";
}

print(end_html());

__END__

The test URL is http://www.sci.fi/~iltzu/cgi-bin/figlet.pl

Now that I think about it, there's no reason not to add ascflip.flf to
the list, since I already have it on the server.  Make that 18 fonts.
-- 
Ilmari Karonen - http://www.sci.fi/~iltzu/
"And, should you resort to sticking a martini olive up their nose,
 implacable universal laws require that they'll _like_ that sort of
 thing."  -- Graydon in r.a.sf.c

Related ASCII art in the Gallery

Explore these categories from our collection of 11,000+ artworks:

 _________
|  _____  |\
| |\ ___| | \
| | |   | | |
| | |___| | |
\ | |____\| |
 \|_________|
 Andy Johnson

  __      _
o'')}____//
 `_/      )
 (_(_/-(_/

[>====]

   ))
 .-#-----.
/_________\
 |[] _ []|
 |  |*|  |

  ,  ,  , , ,
 <(__)> | | |
 | \/ | \_|_/
 \^  ^/   |
 /\--/\  /|
/  \/  \/jgs

     /| __________
O|==|* >__________>
     \|

Make your own ASCII art

Turn images, text or 3D into ASCII, or draw your own – right in your browser.